pareto.cfm
Back to Chart Graphics
<![CDATA[
<cfscript>
// ChartDirector for ColdFusion API Access Point
cd = CreateObject("java", "ChartDirector.CFChart");
// A utility to allow us to create arrays with data in one line of code
function Array() {
var result = ArrayNew(1);
var i = 0;
for (i = 1; i LTE ArrayLen(arguments); i = i + 1)
result[i] = arguments[i];
return result;
}
// The data for the chart
data = Array(40, 15, 7, 5, 2);
// The labels for the chart
labels = Array("Hard Disk", "PCB", "Printer", "CDROM", "Keyboard");
// Create a XYChart object of size 400 x 225 pixels. Use golden background color,
// with a 2 pixel 3D border.
c = cd.XYChart(400, 225, cd.goldColor(), -1, 2);
// Add a title box using Arial Bold/11 pt font. Set the background color to metallic
// blue (9999FF). Use a 1 pixel 3D border.
c.addTitle("Hardware Defects", "Arial Bold", 11).setBackground(cd.metalColor(
"0x9999ff"), -1, 1);
// Set the plotarea at (50, 40) and of 300 x 150 pixels in size, with a silver
// background color.
c.setPlotArea(50, 40, 300, 150, cd.silverColor());
// Add a line layer for the pareto line
lineLayer = c.addLineLayer();
// Compute the pareto line by accumulating the data
lineData = cd.ArrayMath(data);
lineData.acc();
// Set a scaling factor such as the maximum point of the line is scaled to 100
scaleFactor = 100 / lineData.max();
// Add the pareto line using the scaled data. Use deep blue (0x80) as the line color,
// with light blue (0x9999ff) diamond symbols
lineLayer.addDataSet(lineData.mul2(scaleFactor).result(), "0x000080").setDataSymbol(
cd.DiamondSymbol, 9, "0x9999ff");
// Set the line width to 2 pixel
lineLayer.setLineWidth(2);
// Tool tip for the line layer
lineLayer.setHTMLImageMap("", "", "title='Top {={x}+1} items: {value|2}%'");
// Add a multi-color bar layer using the given data.
barLayer = c.addBarLayer3(data);
// Bind the layer to the secondary (right) y-axis.
barLayer.setUseYAxis2();
// Set soft lighting for the bars with light direction from the right
barLayer.setBorderColor(cd.Transparent, cd.softLighting(cd.Right));
// Tool tip for the bar layer
barLayer.setHTMLImageMap("", "", "title='{xLabel}: {value} pieces'");
// Set the labels on the x axis.
c.xAxis().setLabels(labels);
// Set the primary y-axis scale as 0 - 100 with a tick every 20 units
c.yAxis().setLinearScale(0, 100, 20);
// Set the label format of the y-axis label to include a percentage sign
c.yAxis().setLabelFormat("{value}%");
// Add a title to the secondary y-axis
c.yAxis2().setTitle("Frequency");
// Set the secondary y-axis label foramt to show no decimal point
c.yAxis2().setLabelFormat("{value|0}");
// Set the relationship between the two y-axes, which only differ by a scaling factor
c.syncYAxis(1 / scaleFactor);
// Output the chart
chart1URL = c.makeSession(GetPageContext(), "chart1");
// Include tool tip for the chart
imageMap1 = c.getHTMLImageMap("");
</cfscript>
<html>
<body style="margin:5px 0px 0px 5px">
<div style="font-size:18pt; font-family:verdana; font-weight:bold">
Pareto Chart
</div>
<hr style="border:solid 1px #000080" />
<cfoutput>
<div style="font-size:9pt; font-family:verdana; margin-bottom:1.5em">
<a href='viewsource.cfm?file=#CGI.SCRIPT_NAME#'>View Source Code</a>
</div>
<img src="getchart.cfm?#chart1URL#" usemap="##map1" border="0" />
<map name="map1">#imageMap1#</map>
</cfoutput>
</body>
</html>
]]>