finance2.cfm
Back to Chart Graphics
<![CDATA[
<cfscript>
// ChartDirector for ColdFusion API Access Point
cd = CreateObject("java", "ChartDirector.CFChart");
// Create a finance chart demo containing 100 days of data
noOfDays = 100;
// To compute moving averages starting from the first day, we need to get extra data
// points before the first day
extraDays = 30;
// In this exammple, we use a random number generator utility to simulate the data.
// We set up the random table to create 6 cols x (noOfDays + extraDays) rows, using 9
// as the seed.
rantable = cd.RanTable(9, 6, noOfDays + extraDays);
// Set the 1st col to be the timeStamp, starting from Sep 4, 2002, with each row
// representing one day, and counting week days only (jump over Sat and Sun)
rantable.setDateCol(0, CreateDate(2002, 9, 4), 86400, True);
// Set the 2nd, 3rd, 4th and 5th columns to be high, low, open and close data. The
// open value starts from 100, and the daily change is random from -5 to 5.
rantable.setHLOCCols(1, 100, -5, 5);
// Set the 6th column as the vol data from 5 to 25 million
rantable.setCol(5, 50000000, 250000000);
// Now we read the data from the table into arrays
timeStamps = rantable.getCol(0);
highData = rantable.getCol(1);
lowData = rantable.getCol(2);
openData = rantable.getCol(3);
closeData = rantable.getCol(4);
volData = rantable.getCol(5);
// Create a FinanceChart object of width 600 pixels
c = cd.FinanceChart(600);
// Add a title to the chart
c.addTitle("Finance Chart Demonstration");
// Set the data into the finance chart object
c.setData(timeStamps, highData, lowData, openData, closeData, volData, extraDays);
// Add a slow stochastic chart with %K = 14 and %D = 3
c.addSlowStochastic(70, 14, 3, "0x006060", "0x606000");
// Add the main chart with 210 pixels in height
c.addMainChart(210);
// Add a 10 period simple moving average to the main chart, using brown color
c.addSimpleMovingAvg(10, "0x663300");
// Add a 20 period simple moving average to the main chart, using purple color
c.addSimpleMovingAvg(20, "0x9900ff");
// Add an HLOC symbols to the main chart, using green/red for up/down days
c.addCandleStick("0x00ff00", "0xff0000");
// Add 20 days donchian channel to the main chart, using light blue (9999ff) as the
// border and semi-transparent blue (c06666ff) as the fill color
c.addDonchianChannel(20, "0x9999ff", "0xc06666ff");
// Add a 70 pixels volume bars sub-chart to the bottom of the main chart, using
// green/red/grey for up/down/flat days
c.addVolBars(70, "0x99ff99", "0xff9999", "0x808080");
// Append a MACD(26, 12) indicator chart (70 pixels height) after the main chart,
// using 9 days for computing divergence.
c.addMACD(70, 26, 12, 9, "0x0000ff", "0xff00ff", "0x008000");
// Output the chart
chart1URL = c.makeSession(GetPageContext(), "chart1");
</cfscript>
<html>
<body style="margin:5px 0px 0px 5px">
<div style="font-size:18pt; font-family:verdana; font-weight:bold">
Finance Chart (2)
</div>
<hr style="border:solid 1px #000080" />
<cfoutput>
<div style="font-size:9pt; font-family:verdana; margin-bottom:1.5em">
<a href='viewsource.cfm?file=#CGI.SCRIPT_NAME#'>View Source Code</a>
</div>
<img src="getchart.cfm?#chart1URL#" />
</cfoutput>
</body>
</html>
]]>